把我的 .zshrc 讲透：按“原文一段 + 中文解释一段”逐节拆解 ​

# ===== locale / editor =====
# 设置语言、编辑器和基础目录变量。
export LANG=en_US.UTF-8
export LC_CTYPE=$LANG
export EDITOR=nano
export VISUAL=$EDITOR
export XDG_CACHE_HOME=${XDG_CACHE_HOME:-$HOME/.cache}
export DEV49_HOME=${DEV49_HOME:-$HOME/dev49}
export TMP49_DIR=${TMP49_DIR:-$HOME/tmp49}

# ===== platform =====
# 检测当前是否处于 WSL 环境。
export IS_WSL=$([[ -r /proc/version ]] && grep -qi microsoft /proc/version && echo 1 || echo 0)

# ===== path =====
# 去重 path/fpath/cdpath/manpath，并提前注入常用目录。
typeset -gU path fpath cdpath manpath
path=(
  $HOME/.local/bin
  $HOME/.local/share/fnm
  $path
)

# ===== history =====
# 配置历史记录容量与共享策略。
HISTFILE=$HOME/.zsh_history
HISTSIZE=10000
SAVEHIST=10000
setopt APPEND_HISTORY
setopt INC_APPEND_HISTORY
setopt SHARE_HISTORY
setopt EXTENDED_HISTORY
setopt HIST_IGNORE_DUPS
setopt HIST_IGNORE_ALL_DUPS
setopt HIST_FIND_NO_DUPS
setopt HIST_REDUCE_BLANKS
setopt HIST_EXPIRE_DUPS_FIRST
setopt HIST_FCNTL_LOCK

# ===== shell behavior =====
# 开启更顺手的交互行为。
setopt AUTO_CD
setopt INTERACTIVE_COMMENTS
setopt NO_BEEP

# ===== completion =====
# 设置补全匹配、菜单样式与缓存目录。
zstyle ':completion:*' matcher-list 'm:{a-z}={A-Za-z}'
zstyle ':completion:*' menu select
zstyle ':completion:*' list-colors ''
zstyle ':completion:*' use-cache on
zstyle ':completion:*' cache-path "$XDG_CACHE_HOME/zsh/zcompcache"

# ===== oh-my-zsh =====
# 加载 Oh My Zsh、主题和插件。
export ZSH=$HOME/.oh-my-zsh
ZSH_THEME=robbyrussell
plugins=(
  sudo
  extract
  z
)
zstyle ':omz:update' mode reminder
source $ZSH/oh-my-zsh.sh

# ===== fnm =====
# 加载 fnm 环境并启用目录切换自动版本识别。
(( $+commands[fnm] )) && eval "$(fnm env --use-on-cd --shell zsh)"

# ===== fzf =====
# 加载 fzf 的 zsh 集成脚本。
(( $+commands[fzf] )) && source <(fzf --zsh)

# ===== aliases =====
# 定义高频命令别名。
alias q='exit 0'
alias sudo='sudo '
alias c='clear'
alias -- -='cd -'
alias ll='ls -alF'
alias la='ls -A'
alias l='ls -CF'
alias ..='cd ..'
alias ...='cd ../..'
alias grep='grep --color=auto'
alias igrep='grep -i'

# 以对齐方式打印所有环境变量。
penv() {
  printenv | sort | awk -F= '
    { a[NR]=$0; if (length($1)>m) m=length($1) }
    END {
      for (i=1; i<=NR; i++) {
        split(a[i], b, "=")
        key=b[1]
        sub(/^[^=]*=/, "", a[i])
        printf "\033[32m%-*s\033[0m = %s\n", m, key, a[i]
      }
    }'
}

# 按序号打印 path，并标记目录是否存在。
ppath() {
  local i=1 dir color sign
  for dir in $path; do
    if [[ -d $dir ]]; then
      color=32
      sign=OK
    else
      color=31
      sign=NO
    fi
    printf '\e[%sm[%2d] %s\e[0m %s\n' $color $i $sign $dir
    ((i++))
  done
}

# 创建目录并立即进入。
mkcd() {
  mkdir -p -- "$1" && cd -- "$1"
}

# 清空临时目录并进入。
tmp49() {
  rm -rf -- $TMP49_DIR
  mkdir -p -- $TMP49_DIR
  cd -- $TMP49_DIR
}

# 搜索进程；有参数时模糊搜，没有参数时列全量。
pps() {
  (( $# )) && pgrep -af -i -- "$*" || ps -ef
}

# 把 Windows 路径转成 WSL 路径并进入。
cdwin() {
  cd -- "$(wslpath -u "$1")"
}

# 快速进入 Windows 下载目录。
cddd() {
  cdwin "C:\Users\<your-user>\Downloads"
}

# 输出当前 Git 仓库 origin 的网页地址。
git-web() {
  git remote get-url origin | sed -E \
    's#^git@([^:]+):#https://\1/#; s#^ssh://git@#https://#; s#\.git$##'
}

# 执行自定义 Python 工具更新脚本。
update_binaries() {
  uv run "$DEV49_HOME/python/update_binaries.py"
}

# 查看命令的所有来源与最终解析结果。
kan() {
  print '显示所有定义：'
  type -a "$1"
  print
  print '最终执行结果：'
  command -V "$1"
}

# 下载指定模板名的 .gitignore。
gitignore() {
  curl -fsSL "https://raw.githubusercontent.com/github/gitignore/main/$1.gitignore" -o .gitignore
}

# 上传文件或标准输入到 fars.ee。
up-pb() {
  curl -fsS -F "c=@${1:--}" -F p=1 'https://fars.ee/?u=1'
}

# 下载指定网站的 favicon。
favicons49() {
  local url=$1 size=${2:-64} host out
  host=${url#http://}
  host=${host#https://}
  host=${host%%/*}
  out=${host:-favicon}
  curl -fsSL "https://www.google.com/s2/favicons?sz=$size&domain_url=$url" -o "$out.jpg"
}

# 执行整套仓库同步与备份流程。
allinboom() {
  tmp49
  update_binaries
  zsh ~/dev49/scripts/1-clone-all.sh
  zsh ~/dev49/scripts/2-pull-all.sh
  zsh ~/dev49/scripts/3-update-all.sh
  zsh ~/dev49/scripts/4-backup-all.sh
  zsh ~/dev49/AI49/claude.zsh
  print -n '\a'
}

# ===== tmux / ai =====
# 切换 claude配置
ccswitch(){
  cat /mnt/c/Users/<your-user>/.cc-switch/.claude/settings.json > /home/<your-user>/dev49/AI49/claude-settings.json
}
AI_CMD='claude --dangerously-skip-permissions'

# 进入 session：在 tmux 内就切换，不在 tmux 内就 attach
_ta() {
  if [[ -n $TMUX ]]; then
    tmux switch-client -t "$1"
  else
    tmux attach-session -t "$1"
  fi
}

# fzf 选择一个 session
_tpick() {
  tmux list-sessions -F '#S' 2>/dev/null | \
    fzf --prompt='tmux session> ' --height=40% --reverse
}

# 当前目录生成 AI session 名
_tai_name() {
  local name=${PWD:t}
  name=${name//[^[:alnum:]_-]/_}
  print -r -- "ai-$name"
}

# session 不存在则创建；有命令就用命令启动，没有就启动默认 shell
_tensure() {
  local session=$1
  shift
  tmux has-session -t "$session" 2>/dev/null && return 0
  if (( $# )); then
    tmux new-session -d -s "$session" "$@"
  else
    tmux new-session -d -s "$session"
  fi
}

# 创建/进入当前目录对应的 AI session
tai() {
  local session=${1:-$(_tai_name)}
  _tensure "$session" "zsh -ic 'exec $AI_CMD'"
  _ta "$session"
}

# 创建/进入指定 session
tnew() {
  local session=$1
  [[ -z $session ]] && { echo 'usage: tnew <session-name>'; return 1; }
  _tensure "$session"
  _ta "$session"
}

# fzf 选择 session 并进入
ts() {
  local session=$(_tpick)
  [[ -n $session ]] && _ta "$session"
}

# fzf 选择 session 并杀掉
tk() {
  local session=$(_tpick)
  [[ -n $session ]] && tmux kill-session -t "$session"
}

# ===== doctor =====
# 检查当前 shell、WSL 状态、path 和关键命令。
zshrc-doctor() {
  print '== shell =='
  print $SHELL
  print
  print '== wsl =='
  print "IS_WSL=$IS_WSL"
  print
  print '== path =='
  ppath
  print
  print '== commands =='
  local cmd
  for cmd in zsh git tmux node npm python3 uv fzf fnm yazi; do
    (( $+commands[$cmd] )) \
      && printf '[OK] %s -> %s\n' "$cmd" "$commands[$cmd]" \
      || printf '[NO] %s\n' "$cmd"
  done
}